Excel下拉列表和平均函数

问题描述：

目前，我有一个公式可帮助我根据两个下拉列表计算平均值。我管理它，以便即使在任何一个下拉列表为空的情况下也能计算平均值。目前的两下拉安排Excel下拉列表和平均函数

截屏：

我现在想要做同样的事情，但这次有3个下拉列表中工作的平均函数：我想它返回当选择下拉单元格的1个，2个或3个时相应的值。

我在编写公式时不知何故迷路了，并且它返回一个错误。我觉得我没有考虑所有的可能性。

你能帮我吗？

谢谢:)

请参阅[为什么没有代码和示例数据的图像]（http://tinyurl.com/kdxb7le）。 – Jeeped

答

假设你想从你的图片名称标准添加，我想出了下面的公式。这很长，可能有一个更清洁的方式，但似乎工作。

`=IFERROR(IF(AND(A5<>"",B5="",C5=""),AVERAGEIF(Name,A5,Number), 
    IF(AND(A5="",B5<>"",C5=""),AVERAGEIF(size,B5,Number), 
    IF(AND(A5="",B5="",C5<>""),AVERAGEIF(color,C5,Number), 
    IF(AND(A5<>"",B5<>"",C5=""),AVERAGEIFS(Number,Name,A5,size,B5), 
    IF(AND(A5<>"",B5="",C5<>""),AVERAGEIFS(Number,Name,A5,color,C5), 
    IF(AND(A5="",B5<>"",C5<>""),AVERAGEIFS(Number,size,B5,color,C5), 
    AVERAGEIFS(Number,Name,A5,size,B5,color,C5))))))), 
    "No Combo")`

难以阅读，但它的工作原理也一样。建议：使用[Ctrl] + K快速缩进您的代码/公式四个空格，而不是“倒退”它们。保存'back-ticks'进行在线格式化。 – Jeeped

答

当有不匹配的条件不产生任何结果时，您有四个可以满足的条件和错误控制。

A5，B5和C5都可以有值。

A5，B5和C5都没有值。

其中两个A5：C5单元格可以具有值。 _{A5是空白
B5是空白
C5是空白}

其中A5的：C5细胞可具有的值。 _{A5具有值
B5具有值
C5具有值}

A5的任何组合，B5和C5（包括空白）从D9不产生匹配的数字： D14从AVERAGEIFS function导致#DIV/0!错误。

在D5标准公式，

=IFERROR(IF(COUNTA(A5:C5)=3, AVERAGEIFS(D9:D14, A9:A14, A5, B9:B14, B5, C9:C14, C5), 
     IF(COUNTA(A5:C5)=0, AVERAGE(D9:D14), 
     IF(COUNTA(A5:C5)=2, IF(A5="", AVERAGEIFS(D9:D14, B9:B14, B5, C9:C14, C5), 
          IF(B5="", AVERAGEIFS(D9:D14, A9:A14, A5, C9:C14, C5), 
             AVERAGEIFS(D9:D14, A9:A14, A5, B9:B14, B5))), 
     IF(COUNTA(A5:C5)=1, IF(A5<>"", AVERAGEIFS(D9:D14, A9:A14, A5), 
          IF(B5<>"", AVERAGEIFS(D9:D14, B9:B14, B5), 
             AVERAGEIFS(D9:D14, C9:C14, C5))))))), 
     "nothing to avg")

您可以选择保留换行符和多余的空格在公式中。没有任何不利和帮助直观地组织配方。

我只用了AVERAGE和AVERAGEIFS功能简单。 AVERAGEIF函数只是一个仅具有一个标准的AVERAGEIFS，但其参数会翻转以补偿平均范围可能与criteria_range不一样的范围。使用AVERAGEIFS，单独的average_range和criteria_range不是可选的。涉及标准时仅使用AVERAGEIFS意味着您可以使用一种语法。

这比您的原始标准稍微复杂一点，只允许一个标准。随着更多的标准出现更多的DIV/0!错误的可能性增加。要限制基于其他选择的选择，请参阅Conditional Data Validation based on Dropdown List Response以获取想法。

Excel下拉列表和平均函数

相关推荐