重命名子文件夹中的文件的批处理脚本

问题描述：

我需要一个脚本来重命名脚本根目录的所有子文件夹中的所有文件。我做了搜索，发现一些东西，工作，我可以修改（我有点新手/俗人）重命名子文件夹中的文件的批处理脚本

@echo off 
chcp 65001 
setlocal enabledelayedexpansion 
set filename=image 
set /a x=1 
>@rename.txt (
for /r %CD% %%f in (*.jpg) do (
     echo rename "%%f" "!filename!_!x!.jpg" 
     rename "%%f" "!filename!_!x!.jpg" 
    set /a x+=1 
    ) 
) 
endlocal 
pause

但我想这将文件重命名为随机字符串。

我发现了很多可以生成随机字符串的脚本，但我不能让它们在FOR括号内工作。

现在即时通讯坚持

@echo off 
chcp 65001 
setlocal enabledelayedexpansion 
set /a x=%RANDOM%/99 
>@rename.txt (
for /r %CD% %%f in (*.jpg) do (
     echo "%%f" renamed to "!x!.jpg" 
     rename "%%f" "!x!.jpg" 
    set /a x+=%RANDOM%/99 
    ) 
) 
endlocal

，工作正常，但有他的局限性。

任何帮助将不胜感激

答

@echo off 
chcp 65001 
setlocal enableextensions enabledelayedexpansion 
set "alphabet=a b c d f g h i j k l m n p q r s t u v w x y z 0 1 2 3 4 5 6 7 8 9" 
    set "size=0" 
    for %%a in (%alphabet%) do (
     set "a.!size!=%%a" 
     set /a "size+=1" 
    ) 
for /r %CD% %%f in (*.jpg) do (
    set "k=" 
    for /l %%a in (1 1 64) do (
     set /a "r=!random! %% size" 
     for %%b in (!r!) do set "k=!k!!a.%%b!" 
    ) 
    rename "%%f" "!k!.jpg" 
    ) 
endlocal

重命名子文件夹中的文件的批处理脚本

相关推荐