Azure函数/ Azure网站自定义部署脚本过早结束

Question

我有一个Azure函数的自定义批量部署脚本，它过早结束而不会出错。我希望有人能帮助我理解正在发生的事情。

有问题的部分似乎是脚本的“预部署”部分中：

for /F %%f in ('git.exe diff --name-only %PREVIOUS_SCM_COMMIT_ID% %SCM_COMMIT_ID% ^| grep package.json') do (
    SET PACKAGEJSON=%%~f 
    SET PKGFOLDER=!DEPLOYMENT_SOURCE!\!PACKAGEJSON:package.json=! 
    echo "NPM Install: !PKGFOLDER!package.json" 
    pushd "!PKGFOLDER!" 
    npm install --production --progress=false --cache-min=432000 
    npm install --save json-loader --progress=false --cache-min=432000 
    IF !ERRORLEVEL! NEQ 0 goto error 
    popd 
) 

如果的package.json尚未最后两次提交之间修改，脚本跳过这一部分作为预计并继续执行“部署”部分。

如果package.json已被修改，则代码首先按预期工作，然后运行npm安装。然而，然后，它结束时没有错误，并且不会继续到部署部分。在最后一次npm安装运行后，脚本没有额外的输出。

任何人都可以帮助我了解什么是错的？这对我来说是正确的。

完整的脚本如下，它是下列项目的一部分： https://github.com/securityvoid/.deploy

@if "%SCM_TRACE_LEVEL%" NEQ "4" @echo off 
@echo Started: %date% %time% 

:: ---------------------- 
:: KUDU Deployment Script 
:: Version: 1.0.12 
:: ---------------------- 

:: Prerequisites 
:: ------------- 

:: Verify node.js installed 
where node 2>nul >nul 
IF %ERRORLEVEL% NEQ 0 (
    echo Missing node.js executable, please install node.js, if already installed make sure it can be reached from current environment. 
    goto error 
) 

:: Setup 
:: ----- 

setlocal enabledelayedexpansion 

SET ARTIFACTS=%~dp0%..\artifacts 

IF NOT DEFINED DEPLOYMENT_SOURCE (
    SET DEPLOYMENT_SOURCE=%~dp0%. 
) 
echo "Deployment Source: %DEPLOYMENT_SOURCE%" 

IF NOT DEFINED DEPLOYMENT_DIST (
    SET DEPLOYMENT_DIST=%DEPLOYMENT_SOURCE%\dist 
) ELSE (
    ECHO "Deployement Dist already set" 
) 
echo "Deployment Dist: %DEPLOYMENT_DIST%" 

IF NOT DEFINED DEPLOYMENT_TARGET (
    SET DEPLOYMENT_TARGET=%ARTIFACTS%\wwwroot 
) 
echo "Deployment Target: %DEPLOYMENT_TARGET%" 

IF NOT DEFINED NEXT_MANIFEST_PATH (
    SET NEXT_MANIFEST_PATH=%ARTIFACTS%\manifest 

    IF NOT DEFINED PREVIOUS_MANIFEST_PATH (
    SET PREVIOUS_MANIFEST_PATH=%ARTIFACTS%\manifest 
) 
) 

IF NOT DEFINED KUDU_SYNC_CMD (
    :: Install kudu sync 
    echo Installing Kudu Sync 
    call npm install kudusync -g --silent 
    IF !ERRORLEVEL! NEQ 0 goto error 

    :: Locally just running "kuduSync" would also work 
    SET KUDU_SYNC_CMD=%appdata%\npm\kuduSync.cmd 
) 

for /F "tokens=5 delims=.\" %%a in ("%PREVIOUS_MANIFEST_PATH%") do SET PREVIOUS_SCM_COMMIT_ID=%%a 

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: 
:: Pre-Deployment 
:: ---------- 
@echo "Initiating Pre-Deployment: %date% %time%" 
@echo "Previous Commit: %PREVIOUS_SCM_COMMIT_ID% Current Commit: %SCM_COMMIT_ID%" 
for /F %%f in ('git.exe diff --name-only %PREVIOUS_SCM_COMMIT_ID% %SCM_COMMIT_ID% ^| grep package.json') do (
    SET PACKAGEJSON=%%~f 
    SET PKGFOLDER=!DEPLOYMENT_SOURCE!\!PACKAGEJSON:package.json=! 
    echo "NPM Install: !PKGFOLDER!package.json" 
    pushd "!PKGFOLDER!" 
    npm install --production --progress=false --cache-min=432000 
    npm install --save json-loader --progress=false --cache-min=432000 
    IF !ERRORLEVEL! NEQ 0 goto error 
    popd 
) 


:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: 
:: Deployment 
:: ---------- 

@echo "Initiating Deployment: %date% %time%" 

:: 1. Build Script 
node %DEPLOYMENT_SOURCE%\.deploy\deploy.js 

:: 2. KuduSync 
IF /I "%IN_PLACE_DEPLOYMENT%" NEQ "1" (
    call :ExecuteCmd "%KUDU_SYNC_CMD%" -v 50 -f "%DEPLOYMENT_DIST%" -t "%DEPLOYMENT_TARGET%" -n "%NEXT_MANIFEST_PATH%" -p "%PREVIOUS_MANIFEST_PATH%" -i ".git;.hg;.deployment;deploy.cmd" 
    IF !ERRORLEVEL! NEQ 0 goto error 
) 

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: 
goto end 

:: Execute command routine that will echo out when error 
:ExecuteCmd 
setlocal 
set _CMD_=%* 
call %_CMD_% 
if "%ERRORLEVEL%" NEQ "0" echo Failed exitCode=%ERRORLEVEL%, command=%_CMD_% 
exit /b %ERRORLEVEL% 

:error 
endlocal 
echo An error has occurred during web site deployment. 
call :exitSetErrorLevel 
call :exitFromFunction 2>nul 

:exitSetErrorLevel 
exit /b 1 

:exitFromFunction 
() 

:end 
endlocal 
echo Finished successfully. 

Answer 1

问题的根源在于npm是一个批处理文件。当一个批处理文件（你的批处理文件）调用另一个批处理文件时，执行流程将转移到被调用者，一旦它结束工作，执行流程不会返回给调用者。

如果调用是使用call命令完成的，则此行为会更改。

call npm .... 

将执行控制转移到被调用的批处理文件，并在执行流程结束时返回给调用者。

note：暴露的行为是undelaying过程的简化。批处理文件在内存“上下文”内执行。如果没有call命令，则调用的批处理文件会将主叫方“上下文”替换为call命令，从而创建新的“上下文”。

这留下了另外一个问题：如果调用批处理文件传输执行流程npm并且它没有返回，为什么第二个npm命令被执行？

执行批处理文件（或命令行）时，代码块（括号中的代码）将被加载到内存中并作为一个整体进行分析。您的for命令放置在内存中，并且包含在其do子句中的所有命令都将继续运行，直到循环结束。

注：在这种情况下，主叫一批“背景”不相关，但一旦第一npm已被调用（不call）和已被丢弃（被称为上下文代替），其余在for循环被执行的命令（它们仍然在存储器中）在命令行上下文而不是在批次上下文，并且随着“上下文”被丢弃，则setlocal已还原和变量的变化，directoy丢弃更改和延迟扩展。