作为SPARQL构造中的主题字面值查询

Question

我很努力地创建一个正确的SPARQL查询，它将生成正确的格式，以便我可以在其中打开Protege。我们的本体论是关于鸡尾酒的，我们希望在我们的数据库中包含所有DBPedia鸡尾酒，包括配料（dbp:ingredients）和配方（dbp:prep）。在数据库中获得鸡尾酒的效果很好，但其成分和配方不是。现在我有以下查询：？？

CONSTRUCT {?drink dct:subject ?category. 
?drink dbp:prep ?recipe. 
?drink dbp:ingredients ?ingredients. 
?drink rdf:type owl:NamedIndividual . 
?category rdf:type owl:Class. 
dct:subject rdf:type owl:ObjectProperty. 
dbp:prep rdf:type owl:ObjectProperty. 
dbp:ingredient rdf:type owl:Objectproperty. 
} 
WHERE { 
?drink dct:subject ?category. 
?drink dbp:prep ?recipe. 
?drink dbp:ingredients ?ingredients.} 

由于原料和配方，现在没有宣布，它不会在门徒的个人标签显示。但是，当我加入这个到查询的构造物部分：

?recipe rdf:type owl:NamedIndividual. 
?ingredients rdf:type owl:NamedIndividual. 

我得到一个错误：

Virtuoso RDF01 Error Bad variable value in CONSTRUCT: "*5 cL vodka *10 cL orange juice" (tag 246 box flags 0) is not a valid subject, only object of a triple can be a literal

我想是因为准备和DBpedia的成分只是一个字符串，没有任何链接的数据。 但是，如何使这项工作在Protege中显示？

Answer 1

无法将字面值作为RDF三元组的主题。相反，创建配方和配料资源+将字符串值附加为rdfs:comment（或者可能是rdfs:label）可能是一种解决方法。它的工作原理是这样的：

CONSTRUCT { 
?drink dct:subject ?category. 
?drink dbp:prep ?recipe. 
?drink dbp:ingredients ?ingredients. 
?drink rdf:type owl:NamedIndividual . 
?category rdf:type owl:Class. 
dct:subject rdf:type owl:ObjectProperty. 
dbp:prep rdf:type owl:ObjectProperty. 
dbp:ingredients rdf:type owl:Objectproperty. 
# add string values as rdfs:comment 
?recipe rdfs:comment ?recipe_str . 
?ingredients rdfs:comment ?ingredients_str 
} 
WHERE { 
?drink dct:subject ?category. 
?drink dbp:prep ?recipe_str. 
?drink dbp:ingredients ?ingredients_str. 
BIND(URI(CONCAT("http://dbpedia.org/resource/recipe", MD5(STR(?recipe_str)))) as ?recipe) 
BIND(URI(CONCAT("http://dbpedia.org/resource/ingredients", MD5(STR(?ingredients_str)))) as ?ingredients) 
} 

注意，它会以某种方式如果配方（RESP成分）已经是一个资源失败。它不适用于DBpedia上的dbp:prep和dbp:ingredients，但一般来说，如果您不确定，并且您有一些实际上允许资源和文字的rdf:Property，则需要正确处理此问题。通过使用IF-ELSE结构：

BIND(IF(isLiteral(?recipe_str), URI(CONCAT("http://dbpedia.org/resource/recipe", MD5(STR(?recipe_str)))), ?recipe_str) as ?recipe) 
BIND(IF(isLiteral(?ingredients_str), URI(CONCAT("http://dbpedia.org/resource/ingredients", MD5(STR(?ingredients_str)))), ?ingredients_str) as ?ingredients) 

，你也必须省略rdfs:comment三倍那么确实...