antlr语法定义

Question

我对编译器理论比较陌生，我只是想创建一个语法来解析一些比较以便稍后评估它们。我发现antlr是一个强大的工具来指定语法。根据我在理论中学到的知识，我知道具有较高优先级的运算符必须比具有较低优先级的运算符在更深层次上更低。另外，如果我想要一些规则保持联想，我知道我必须将递归设置在规则的左侧。知道我已经创建了一个基本语法来使用& &，||，！=，==，<，>，< =，> =，（，）和！

start 
: orExpr 
; 

orExpr 
: orExpr OR andExpr 
| andExpr 
; 

andExpr 
: andExpr AND eqNotEqExpr 
| eqNotEqExpr 
; 

eqNotEqExpr 
: eqNotEqExpr NEQ compExpr 
| eqNotEqExpr EQ compExpr 
| compExpr 
; 

compExpr 
: compExpr LT compExpr 
| compExpr GT compExpr 
| compExpr LTEQ compExpr 
| compExpr GTEQ compExpr 
| notExpr 
; 

notExpr 
: NOT notExpr 
| parExpr 
; 

parExpr 
: OPAR orExpr CPAR 
| id 
; 

id 
: INT 
| FLOAT 
| TRUE 
| FALSE 
| ID 
| STRING 
| NULL 
; 

在互联网然而搜索我已经找到了不同的方式来指定上述语法不遵循我提到关于运算符优先级上面的规则和左结合：

start 
: expr 
; 

expr 
: NOT expr        //notExpr 
| expr op=(LTEQ | GTEQ | LT | GT) expr //relationalExpr 
| expr op=(EQ | NEQ) expr    //equalityExpr 
| expr AND expr      //andExpr 
| expr OR expr       //orExpr 
| atom         //atomExpr 
; 

atom 
: OPAR expr CPAR //parExpr 
| (INT | FLOAT) //numberAtom 
| (TRUE | FALSE) //booleanAtom 
| ID    //idAtom 
| STRING   //stringAtom 
| NULL   //nullAtom 
; 

有人可以解释为什么这样definig的语法也适用？是否因为antlr或其他类型的语法定义的特定处理？

下面有对语法定义的运营商和ID：

OR : '||'; 
AND : '&&'; 
EQ : '=='; 
NEQ : '!='; 
GT : '>'; 
LT : '<'; 
GTEQ : '>='; 
LTEQ : '<='; 
NOT : '!'; 

OPAR : '('; 
CPAR : ')'; 

TRUE : 'true'; 
FALSE : 'false'; 
NULL : 'null'; 

ID 
: [a-zA-Z_] [a-zA-Z_0-9]* 
; 

INT 
: [0-9]+ 
; 

FLOAT 
: [0-9]+ '.' [0-9]* 
| '.' [0-9]+ 
; 

STRING 
: '"' (~["\r\n] | '""')* '"' 
; 

COMMENT 
: '//' ~[\r\n]* -> skip 
; 

SPACE 
: [ \t\r\n] -> skip 
; 

OTHER 
: . 
; 

Answer 1

这是特定于ANTLR V4。

在这种情况下，像这样的规则将被重写为与左手递归消除步骤的一部分手动完成的操作相同的操作。 ANTLR这样做是为了方便，因为LL语法不能包含左递归规则，因为直接将这样的规则转换为解析器代码会在代码中产生无限递归（一种非规则地调用自身的函数）。

the docs page about left-recursion有更多信息和转换示例。