使用msscript控件在vbscript中获取所有变量值

问题描述：

有没有什么办法可以在运行时获取脚本中的所有变量值。使用msscript控件在vbscript中获取所有变量值

考虑以下vbscript代码。

var1= 5 
Var2= 6 

For i=0 To 5 
    Msgbox i 
Next

如何使用msscript控件实现它，我应该能够在运行时检索所有变量？

我期待为vbscript实现一个调试器我可以在运行时像下面那样列出所有变量。

var1=5 
Var2=6 
i=5

对此的任何帮助将不胜感激。

提前致谢！

答

你在这里！将下面的代码保存为VBScript文件：

' VBS code variables to be fetched from 
sVBScriptDebug = _ 
    "var1= 5" & vbCrLf & _ 
    "Var2= 6" & vbCrLf & _ 
    vbCrLf & _ 
    "For i=0 To 5" & vbCrLf & _ 
    " Msgbox i" & vbCrLf & _ 
    "Next" 

' ScriptControl to be used for debug purposes 
Set oScrCtlDebug = CreateObject("MSScriptControl.ScriptControl") 
oScrCtlDebug.Language = "VBScript" 
oScrCtlDebug.AddCode sVBScriptDebug 
' Me object from debug script 
Set oMeDebug = oScrCtlDebug.Eval("Me") 

' ScriptControl for JScript utility function pushing all object's properties to array 
Set oScrCtlUtil = CreateObject("MSScriptControl.ScriptControl") 
oScrCtlUtil.Language = "JavaScript" 
oScrCtlUtil.Eval("Enum=function(x){this.x=new Array();for (var i in x) {this.x[i]=i};return this.x}") 
' Retrieve JScript this object 
Set oJSGlobal = oScrCtlUtil.Eval("this") 

' Cycle through all debug script Me object properties, that actually are fetched global scope variables 
sRes = "" 
For Each sVar In oJSGlobal.Enum(oMeDebug) 
    sRes = sRes & sVar & "=" & oScrCtlDebug.Eval(sVar) & vbCrLf 
Next 
MsgBox sRes

使用msscript控件在vbscript中获取所有变量值

相关推荐