将函数输出分配给变量Excel的错误VBA

Question

我正在使用从Microsoft复制的函数，该函数需要一个列号并重新分配列字母。我需要这样做来创建一个公式。我一整天都在研究，无法确定我错误的原因（我也试图将其作为子过程来完成）。该功能位于其自己的模块中。我测试了它和它的作品罚款：

Function ConvertToLetter(ByRef iCol As Integer) As String 
    Dim iAlpha As Integer 
    Dim iRemainder As Integer 
    iAlpha = Int(iCol/27) 
    iRemainder = iCol - (iAlpha * 26) 
    If iAlpha > 0 Then 
    ConvertToLetter = Chr(iAlpha + 64) 
    End If 
    If iRemainder > 0 Then 
    ConvertToLetter = ConvertToLetter & Chr(iRemainder + 64) 
    End If 
End Function 

这是给我的错误代码是：

For groups = 1 To i ' level 1 grouping 
    For iCol = 24 To 136 
     rCol = ConvertToLetter(iCol) 
     Cells(Start(groups) - 1, rCol).Formula = "=COUNTA(" & rCol & Start(groups) & ":" & rCol & Finish(groups) & ")" 
    Next 
Next 

我试图函数代入公式本身：

Cells(Start(groups) - 1, ConvertToLetter(iCol)).Formula = "=COUNTA(" & ConvertToLetter(iCol) & Start(groups) & ":" & ConvertToLetter(iCol) & Finish(groups) & ")" 

的调试器使其通过第一个函数调用，但不是第二个。我收到的错误是“期待变量或过程，而不是模块”的类型。在第二种情况下，我得到了其他的错误，而我的头很模糊，我不记得他们。

任何帮助，非常感谢。我已经用完了想法。非常感谢！

Answer 1

你几乎不必列转换为文字。首先考虑使用FormulaR1C1

For groups = 1 To i ' level 1 grouping 
    For iCol = 24 To 136 
     lLast = Finish(groups) - Start(groups) + 1 
     Sheet1.Cells(Start(groups) - 1, iCol).FormulaR1C1 = _ 
      "=COUNTA(R[1]C:R[" & lLast & "]C)" 
    Next iCol 
Next groups 

如果你不喜欢R1C1，您可以用地址更直接

For groups = 1 To i ' level 1 grouping 
    For iCol = 24 To 136 
     Set rStart = Sheet1.Cells(Start(groups), iCol) 
     Set rEnd = Sheet1.Cells(Finish(groups), iCol) 

     rStart.Offset(-1, 0).Formula = _ 
      "=COUNTA(" & rStart.Address & ":" & rEnd.Address & ")" 

    Next iCol 
Next groups 

Answer 2

以下函数将列号转换为字母：它利用了.Address方法来大大简化生活。

Function convertToLetter(colnum) 
mycell = [A1].Offset(0, colnum - 1).Address 
convertToLetter = Mid(mycell, 2, Len(mycell) - 3) 
End Function 

但现在，我看你的代码 - 当您使用Cells功能，你应该用数字，而不是字母调用它。所以你有另一个问题！

尝试以下操作：

For groups = 1 To i ' level 1 grouping 
    For iCol = 24 To 136 
     rCol = ConvertToLetter(iCol) 
     Cells(Start(groups) - 1, iCol).Formula = "=COUNTA(" & rCol & Start(groups) & ":" & rCol & Finish(groups) & ")" 
    Next 
Next 

注意我在发言的Cells(Start(groups)-1, iCol) =部分使用iCol不rCol。它可能不是唯一的错误...

Answer 3

您使用的功能是错误的。检查这个例子

Sub Sample() 
    Dim iCol As Integer 
    For iCol = 131 To 134 
     Debug.Print iCol; ConvertToLetter(iCol) 
    Next iCol 
End Sub 


Function ConvertToLetter(ByRef iCol As Integer) As String 
    Dim iAlpha As Integer 
    Dim iRemainder As Integer 
    iAlpha = Int(iCol/27) 
    iRemainder = iCol - (iAlpha * 26) 
    If iAlpha > 0 Then 
     ConvertToLetter = Chr(iAlpha + 64) 
    End If 
    If iRemainder > 0 Then 
     ConvertToLetter = ConvertToLetter & Chr(iRemainder + 64) 
    End If 
End Function 

输出

131 D[ 
132 D\ 
133 D] 
134 D^ 

使用此代码，这是我从我提到的链接回升。

rcol = Split(Cells(, iCol).Address, "$")(1) 

代替

rCol = ConvertToLetter(iCol)