添加到单元格的公式，但不删除公式

问题描述：

假设电池A5中有以下公式：=SUM(A1:A5)添加到单元格的公式，但不删除公式

我想用VBA加1，这个公式，使其=SUM(A1:A5) + 1

我已经试过Range("A5") = Range("A5") + 1但是这只是将其改为硬编码数字而不是公式+1。我怎样才能解决这个问题？

感谢您的帮助！

答

这样的事情，其中包括式生存测试

If Range("A5").HasFormula Then Range("A5").Formula = Range("A5").Formula & "+1"

更新：要做到这一点非常快的大选择的细胞只有自动更新公式您应使用variant arrays

更改为strAdd = "+1"为您的后缀追加

'Press Alt + F11 to open the Visual Basic Editor (VBE) 
'From the Menu, choose Insert-Module. 
'Paste the code into the right-hand code window. 
'Press Alt + F11 to close the VBE 
'In Xl2003 Goto Tools … Macro … Macros and double-click UpdateFormulae 

Sub UpdateFormulae() 
    Dim rng1 As Range 
    Dim rngArea As Range 
    Dim lngRow As Long 
    Dim lngCol As Long 
    Dim lngCalc As Long 
    Dim X() 
    Dim strAdd As String  


    On Error Resume Next 
    Set rng1 = Application.InputBox("Select range for the replacement of forumlae", "User select", Selection.Address, , , , , 8) 
    Set rng1 = rng1.SpecialCells(xlCellTypeFormulas) 
    If rng1 Is Nothing Then Exit Sub 
    On Error GoTo 0 

    strAdd = "+1" 

    'Speed up the code by turning off screenupdating and setting calculation to manual 
    'Disable any code events that may occur when writing to cells 
    With Application 
     lngCalc = .Calculation 
     .ScreenUpdating = False 
     .Calculation = xlCalculationManual 
     .EnableEvents = False 
    End With 

    'Test each area in the user selected range 

    'Non contiguous range areas are common when using SpecialCells to define specific cell types to work on 
    For Each rngArea In rng1.Areas 
     'The most common outcome is used for the True outcome to optimise code speed 
     If rngArea.Cells.Count > 1 Then 
      'If there is more than once cell then set the variant array to the dimensions of the range area 
      'Using Value2 provides a useful speed improvement over Value. On my testing it was 2% on blank cells, up to 10% on non-blanks 
      X = rngArea.Formula 
      For lngRow = 1 To rngArea.Rows.Count 
       For lngCol = 1 To rngArea.Columns.Count 
        'replace the leading zeroes 
        X(lngRow, lngCol) = X(lngRow, lngCol) & strAdd 
       Next lngCol 
      Next lngRow 
      'Dump the updated array with new formulae back over the initial range 
      rngArea.Value2 = X 
     Else 
      'caters for a single cell range area. No variant array required 
      rngArea.Value2 = rngArea.Formula & strAdd 
     End If 
    Next rngArea 

    'cleanup the Application settings 
    With Application 
     .ScreenUpdating = True 
     .Calculation = lngCalc 
     .EnableEvents = True 
    End With 
End Sub

很难与Excel MVP和VBA专家竞争如此迅速的答案:) - +1 btw – JMax

这么彻底！ –

一个问题：为什么是“rngArea.Value2 = X”，而不是“rngArea.Formula = X”？两者似乎都是一样的，但我会认为Value2会将单元格内容转换为...值。 –

答

Range("A5").Formula = Range("A5").Formula & "+1"

添加到单元格的公式，但不删除公式

相关推荐