通过公式（Excel）更改较大单元格区域中的单元格时的时间戳

Question

作为this问题的后续问题，每当通过单元格范围的公式更改单元格时，我需要在相邻单元格中添加时间戳。

我知道这意味着构建一个数组来存储以前的值到下面的代码（它实现了相同的，但只为一个单元格），并会感谢任何帮助实现这一点。

下面是单个电池的工作原理代码...

在Sheet1中单元格A1，把这个公式

=Sheet2!A1+1 

现在在模块粘贴此代码

Public PrevVal As Variant 

粘贴这在纸张代码区域

Private Sub Worksheet_Calculate() 
    If Range("A1").Value <> PrevVal Then 
     Range("B1").Value = Format(Now, "dd/mm/yyyy hh:mm:ss") 
     PrevVal = Range("A1").Value 
    End If 
End Sub 

而且最后放在ThisWorkbook代码区粘贴此代码

Private Sub Workbook_Open() 
    PrevVal = Sheet1.Range("A1").Value 
End Sub 

Answer 1

你可以保持在Dictionary以前的值，而不是一个数组。要使用字典，你需要添加一个引用到微软脚本运行时库

（工具>参考> Microsoft脚本运行时库）

---

标准模块

Public PrevVal As Dictionary 

---

ThisWorkbook模块

Private Sub Workbook_Open() 
    Dim r As Range 
    Set PrevVal = New Dictionary 
    For Each r In Worksheets("Sheet1").Range("A1:A10") 
     PrevVal.Add Item:=r.Value, Key:=r.Address 
    Next r 
End Sub 

---

表模块

Private Sub Worksheet_Calculate() 
    Dim v As Variant 

    For Each v In PrevVal.Keys() 
     If Range(v).Value <> PrevVal(v) Then 
      Range(v).Offset(0, 1).Value = Format(Now, "dd/mm/yyyy hh:mm:ss") 
      PrevVal(v) = Range(v).Value 
     End If 
    Next v 
End Sub