方法选择（运行时错误1004）

问题描述：

我想找到某个单元格，并在给定单元格的单元格偏移量中插入一个值（从另一本书中复制）。我写的代码，但错误弹出方法选择（运行时错误1004）

运行时错误1004选择方法的范围类失败

在代码行：r.Offset(6, 5).Select

Sub связатьцифирь3() 

    Dim book1 As Workbook 
    Dim book2 As Workbook 
    Dim r As Range 
    Dim firstAddress As String 

    Set book1 = Workbooks.Open("E:\Super M\Проект ставки\Решение\цифирь.xlsx") 
    Set book2 = Workbooks.Open("E:\Super M\Проект ставки\Поиск решения\Усов 4\БАЗА ДАННЫХ\прошлый сезон\Англия\1-ое место\54.xlsx") 
    'переходим в активную страницу откуда надо скопировать данные' 
    book2.Worksheets("54").Activate 
    Range("AP100").Copy 

    'ищемс 
    With book1.Worksheets("Лист1").Range("A1:CV808") 

     Set r = .Find(What:="54") 
     If Not r Is Nothing Then 
      firstAddress = r.Address 
      Do 
       'условие для страны 
       If r.Offset(3, 0).Text = "Англия" Then 
        r.Offset(6, 5).Select 
        Selection.PasteSpecial Paste:=xlPasteValues 
       End If    
       Set r = .FindNext(r)    
      Loop While Not r Is Nothing And r.Address <> firstAddress 
     End If 
    End With 

End Sub

不确定为什么你会得到这个错误，但你为什么使用'Select'？为什么不使用'r.Offset（6，5）.PasteSpecial xlPasteValues'？ –

@ShaiRado错误是因为那时候活跃的WB是'book2'。但是，当然，正如你所说的那样，这里不需要“选择”。 –

谢谢。现在程序工作 – maxim465

答

有没有必要Activate的book2.Worksheets("54")，后来r.Offset(6, 5).Select和再次使用Selection，你应该尽量保持Copy >>Paste接近你可以：

book2.Worksheets("54").Range("AP100").Copy 
r.Offset(6, 5).PasteSpecial xlPasteValues

代码

Sub связатьцифирь3() 

    Dim book1 As Workbook 
    Dim book2 As Workbook 
    Dim r As Range 
    Dim firstAddress As String 

    Set book1 = Workbooks.Open("E:\Super M\Проект ставки\Решение\цифирь.xlsx") 
    Set book2 = Workbooks.Open("E:\Super M\Проект ставки\Поиск решения\Усов 4\БАЗА ДАННЫХ\прошлый сезон\Англия\1-ое место\54.xlsx") 

    'ищемс 
    With book1.Worksheets("Лист1").Range("A1:CV808") 

     Set r = .Find(What:="54") 
     If Not r Is Nothing Then 
      firstAddress = r.Address 
      Do 
       'условие для страны 
       If r.Offset(3, 0).Value2 = "Англия" Then 
        book2.Worksheets("54").Range("AP100").Copy 
        r.Offset(6, 5).PasteSpecial xlPasteValues 
       End If 
       Set r = .FindNext(r) 
      Loop While Not r Is Nothing And r.Address <> firstAddress 
     End If 
    End With 

End Sub

答

您尝试选择范围在不活动的工作表中，这是原因。
尝试先激活或按照Shai的建议进行操作。

方法选择（运行时错误1004）

相关推荐