自定义着色器不能在Android上工作
我将等离子球着色器从Shadertoy移植到Unity,作为图像效果附加到相机上。它可以在编辑器和Windows独立版本上正常工作。它不适用于Android设备。 它在Android上闪烁蓝色和黑色图像。自定义着色器不能在Android上工作
下面是它看起来像在Unity编辑器和Windows编译:
下面是它看起来像在Android上:
所移植的着色器代码:
Shader "Hidden/Plasma Space Ball Image Effect"
{
Properties
{
iChannel0("iChannel0", 2D) = "white" {}
//[MaterialToggle] _isToggled("isToggle", Float) = 0
}
SubShader
{
// No culling or depth
Cull Off ZWrite Off ZTest Always
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 uv : TEXCOORD0;
};
struct v2f
{
float2 uv : TEXCOORD0;
float4 vertex : SV_POSITION;
};
v2f vert(appdata v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.uv = v.uv;
return o;
}
sampler2D iChannel0;
//Ported from https://www.shadertoy.com/view/MstXzf
float3 hb(float2 pos, float t, float time, float2 rot, float size, sampler2D tex0)
{
float2 newUv = 0.2*(pos/(1.2 - t) + 0.5*time*rot);
//float texSample = texture(tex0, newUv).b;
float texSample = tex2D(tex0, newUv).b;
float uOff = 0.2*(texSample + 0.3*time); //lsf3RH
float2 starUV = newUv + float2(uOff, 0.0);
//return float3(0.3, 0.3, 1.0) + 1.3*texture(tex0, starUV).b;
return float3(0.3, 0.3, 1.0) + 1.3*tex2D(tex0, starUV).b;
}
float4 blob(float2 uv, float size, float time, sampler2D tex0)
{
float2 center = float2(0., 0.);
float2 pos = center - uv;
float t = length(pos);
float st = size - t;
float2 rot = 0.005*float2(sin(time/16.), sin(time/12.)); //MslGWN
float alpha = smoothstep(0.0, 0.2*size, st);
float3 col = hb(pos, t, time, rot, size, tex0);
float a1 = smoothstep(-1.4, -1.0, -col.b);
col = lerp(col, hb(pos, t, -time, -rot, size, tex0), a1);
col += 0.8*exp(-12.*abs(t - 0.8*size)/size);
float a2 = smoothstep(-1.4, -1.0, -col.b);
alpha -= a2;
//float crosshair = float((abs(pos.x) < 0.005 && abs(pos.y) < 0.15) || (abs(pos.y) < 0.005&&abs(pos.x) < 0.15));
//return float4(col, alpha) + crosshair;
return float4(col, alpha);
}
float4 main_(float2 uv, float size)
{
return blob(uv, size, _Time.y, iChannel0);
}
fixed4 frag(v2f i) : SV_Target
{
float4 fragColor = 0;
float2 fragCoord = i.vertex.xy;
///---------------------------------------------------
float2 uv = fragCoord.xy/_ScreenParams.xy;
float2 cr = uv*2. - 1.;
cr.x *= _ScreenParams.x/_ScreenParams.y;
//late addition to elaborate background motion, could be reused later on
float2 rot = 0.5*float2(sin(_Time.y/16.), sin(_Time.y/12.));
float4 ball = clamp(main_(cr, sin(_Time.y)*0.05 + 0.5 + 0.5), 0., 1.);
//float3 bg = float3(0.7, 0.7, 1.0)*texture(iChannel0, uv + rot + 0.1*ball.rb).b;
float3 bg = float3(0.7, 0.7, 1.0)*tex2D(iChannel0, uv + rot + 0.1*ball.rb).b;
//simulated gl blend
fragColor = float4(lerp(bg, ball.rgb, ball.a), 1.0);
//fragColor = lerp(fragColor,tex2D(iChannel0, i.uv).rgba,.5);
return fragColor;
}
ENDCG
}
}
}
您可以在上面的着色器中找到用于iChannel0
输入插槽here的图像。
事情我已经尝试:
- 添加着色器的图形设置,以便统一将在构建过程中包括 它。
- 禁用Auto Graphics API并尝试使用OpenGLES2和OpenGLES3。
- 使用Android Studio检查日志。完全没有错误/警告。
这些都解决了这个问题,我跑出了一些东西尝试。
软件和设备信息是否有帮助:
- 统一4.4.2
这是用于学习和教育目的,因为我学习GLSL 5.6.0f3
为什么它在Android上闪烁蓝色和黑色图像?
您需要为OpenGLES2的片段着色器中的位置使用VPOS语义。
从Unity docs:
片段着色器能够接收正被呈现为 特殊VPOS语义的像素的位置。此功能只存在于着色器 模型3.0开始,因此着色器需要具有#pragma目标3.0 编译指令。
因此,要获得屏幕空间位置:
// note: no SV_POSITION in this struct
struct v2f {
float2 uv : TEXCOORD0;
};
v2f vert (
float4 vertex : POSITION, // vertex position input
float2 uv : TEXCOORD0, // texture coordinate input
out float4 outpos : SV_POSITION // clip space position output
)
{
v2f o;
o.uv = uv;
outpos = UnityObjectToClipPos(vertex);
return o;
}
fixed4 frag (v2f i, UNITY_VPOS_TYPE screenPos : VPOS) : SV_Target
{
// screenPos.xy will contain pixel integer coordinates.
float4 fragColor = 0;
float2 fragCoord = screenPos;
但是你已经传递的UV所以也许你可以使用那些?
float2 uv = i.uv;
事实证明我错了。你不要在OpenGLES2片段着色器你.. 0获得剪辑空间位置
我做了一个小测试着色器(也许有人可以解释一下吗?):
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
float4 vert (float4 vertex : POSITION) : SV_Position
{
return UnityObjectToClipPos(vertex);
}
fixed4 frag (float4 screenPos : SV_Position) : SV_Target
{
float uvx = screenPos.x/_ScreenParams.x;
return float4(uvx, 0., 0., 1.);
}
ENDCG
和线float uvx = screenPos.x/_ScreenParams.x;
被编译为tmpvar_2.x = (0.0/_ScreenParams.x); // OpenGLES2
u_xlat0 = gl_FragCoord.x/_ScreenParams.x; // OpenGLES3
但是如果你使用的VPOS
语义fixed4 frag (float4 screenPos : VPOS) : SV_Target
在同一行被编译成tmpvar_2.x = (gl_FragCoord.x/_ScreenParams.x); // OpenGLES2
u_xlat0 = gl_FragCoord.x/_ScreenParams.x; // OpenGLES3
所以对于OpenGLES2它看起来像你需要使用VPOS语义来获得在片段着色器的屏幕空间位置。
感谢您的更新答案和解释。我没有通知这件事。这实际上可能是一个错误。 – Programmer