如何在WMI连接中处理不可用的计算机？

问题描述：

我想评估连接到我的域的计算机的内存和其他详细信息。我正在做的是将计算机名称写入文本文件，每行一个。脚本将逐个读取文件（主机名），收集信息并将其写入文件。这工作正常。如何在WMI连接中处理不可用的计算机？

问题是，如果一台计算机不可用，那么它会造成问题。例如，如果第一个主机名可用，第二个主机名不可用，则它会不断重复显示相同的信息。

INPUT_FILE_NAME = "D:\tmp\Computer.txt" 
Const FOR_READING = 1 
Const HKEY_LOCAL_MACHINE = &H80000002 
strRegKey = "SYSTEM\CurrentControlSet\Services\Tcpip\Parameters" 

Set objFSO = CreateObject("Scripting.FileSystemObject") 

Set objFile = objFSO.OpenTextFile(INPUT_FILE_NAME, FOR_READING) 
strComputers = objFile.ReadAll 
objFile.Close 

arrComputers = Split(strComputers, vbCrLf) 

For Each strComputer In arrComputers 
    On Error Resume Next 
    Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!" & _ 
    "//./root/default:StdRegProv") 
    objReg.GetStringValue HKEY_LOCAL_MACHINE, strRegKey, "Hostname", strHostname 

    Set objWMIService = GetObject("winmgmts:" _ 
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2") 
    Set colPageFiles = objWMIService.ExecQuery _ 
    ("Select * from Win32_PageFileUsage") 
    For each objPageFile in colPageFiles 
    Wscript.Echo "Host Name: " & strHostName, _ 
     "AllocatedBaseSize: "& vbTab & objPageFile.AllocatedBaseSize, _ 
     "CurrentUsage: "& vbTab & objPageFile.CurrentUsage, _ 
     "Description: "& vbTab & objPageFile.Description, _ 
     "InstallDate: "& vbTab & objPageFile.InstallDate, _ 
     "Name: " & vbTab & objPageFile.Name, _ 
     "PeakUsage: " & vbTab & objPageFile.PeakUsage 
    Next 
Next

您可以使用OERN而不检查重要操作的成功/失败。请参阅http://stackoverflow.com/a/24685438/603855以及那里的链接，以找到适当处理“异常”的策略。 –

答

当GetObject()失败，该变量objWMIService保留其以前的值，所以你一遍又一遍的报告相同的主机，直到GetObject()可以连接到主机或循环终止。更改此：

Set objWMIService = GetObject("winmgmts:" _ 
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2") 
Set colPageFiles = objWMIService.ExecQuery _ 
    ("Select * from Win32_PageFileUsage") 
For each objPageFile in colPageFiles 
    Wscript.Echo "Host Name: " & strHostName, _ 
    "AllocatedBaseSize: "& vbTab & objPageFile.AllocatedBaseSize, _ 
    "CurrentUsage: "& vbTab & objPageFile.CurrentUsage, _ 
    "Description: "& vbTab & objPageFile.Description, _ 
    "InstallDate: "& vbTab & objPageFile.InstallDate, _ 
    "Name: " & vbTab & objPageFile.Name, _ 
    "PeakUsage: " & vbTab & objPageFile.PeakUsage 
Next

到这一点：

Set objWMIService = Nothing 
Set objWMIService = GetObject("winmgmts:" _ 
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2") 
If Not objWMIService Is Nothing Then 
    Set colPageFiles = objWMIService.ExecQuery _ 
    ("Select * from Win32_PageFileUsage") 
    For each objPageFile in colPageFiles 
    Wscript.Echo "Host Name: " & strHostName, _ 
     "AllocatedBaseSize: "& vbTab & objPageFile.AllocatedBaseSize, _ 
     "CurrentUsage: "& vbTab & objPageFile.CurrentUsage, _ 
     "Description: "& vbTab & objPageFile.Description, _ 
     "InstallDate: "& vbTab & objPageFile.InstallDate, _ 
     "Name: " & vbTab & objPageFile.Name, _ 
     "PeakUsage: " & vbTab & objPageFile.PeakUsage 
    Next 
Else WScript.Echo strComputer & " unavailable." End If

，问题就会消失。

在不同的音符，第2行中外环将始终检索本地计算机的主机名：

Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!" & _ 
    "//./root/default:StdRegProv") 
objReg.GetStringValue HKEY_LOCAL_MACHINE, strRegKey, "Hostname", strHostname

如果这是你真正想要的东西，你应该向外移动的代码环路，因为strHostname的值不会改变：

Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!" & _ 
    "//./root/default:StdRegProv") 
objReg.GetStringValue HKEY_LOCAL_MACHINE, strRegKey, "Hostname", strHostname 
For Each strComputer In arrComputers 
    '... 
Next

如果你真的想在远程计算机的名称（这将使很多更有意义时，Infor公司的其余部分mation也来自远程计算机），您可以简单地使用strComputer并完全删除注册表查询。

如何在WMI连接中处理不可用的计算机？

相关推荐