[UnityShader入门精要读书笔记]26.顶点动画
流动的河流
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
Shader "Unlit/ScrollRiver"
{
Properties
{
//河流纹理
_MainTex ("Texture", 2D) = "white" {}
//整体颜色
_Color ("Color", Color) = (1,1,1,1)
//控制水流波动幅度
_Magnitude ("Distortion Magnitude", Float) = 1
//波动频率
_Freqency ("Distortion Frequency", Float) = 1
//波长的倒数(值越大,波长越小)
_InvWaveLength ("Distortion Inverse Wave Length", Float) = 10
//控制河流纹理的移动速度。
_Speed ("Speed", Float) = 0.5
}
SubShader
{
//DisableBatching,一些SubShader在使用Unity的批处理功能时会出现问题,这是可以通过该标签来直接指明是否对该SubShader使用批处理。而这些需要特殊处理的SubShader通常就是指包含了模型空间的顶点动画的Shader。这是因为,批处理会合并所有相关的模型,而这些模型各自的模型空间就会丢失。
Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" "DisableBatching"="True" }
LOD 100
Pass
{
Tags { "LightMode"="ForwardBase" }
ZWrite Off
Blend SrcAlpha OneMinusSrcAlpha
Cull Off
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
// make fog work
#pragma multi_compile_fog
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 texcoord : TEXCOORD0;
};
struct v2f
{
float2 uv : TEXCOORD0;
float4 pos : SV_POSITION;
};
sampler2D _MainTex;
float4 _MainTex_ST;
float4 _Color;
float _Magnitude;
float _Freqency;
float _InvWaveLength;
float _Speed;
v2f vert (appdata v)
{
v2f o;
float4 offset;
//首先计算顶点位移量,我们只希望对顶点的x方向进行位移,因此yzw的位移量被设置为0。然后,我们利用_Freqency属性和内置的_Time.y变量来控制正弦函数的频率。为了让不同位置具有不同的位移,我们对上述结果加上了模型空间下的位置分量,并乘以_InvWaveLength来控制波长。最后,我们对结果值乘以_Magnitude属性来控制波动幅度,得到最终位移。
offset.yzw = float3(0.0, 0.0, 0.0);
offset.x = sin(_Freqency * _Time.y + v.vertex * _InvWaveLength + v.vertex.y * _InvWaveLength + v.vertex.z * _InvWaveLength) * _Magnitude;
o.pos = UnityObjectToClipPos(v.vertex + offset);
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
o.uv += float2(0.0, _Time.y * _Speed);
return o;
}
fixed4 frag (v2f i) : SV_Target
{
fixed4 c = tex2D(_MainTex, i.uv);
c.rgb *= _Color.rgb;
return c;
}
ENDCG
}
}
}
广告牌
另一种常见的顶点动画技术就是广告牌技术。广告牌技术会根据视角方向来旋转一个被纹理着色的多边形,使得多边形看起来好像总是面对着摄像机。广告牌技术的本质就是构建旋转矩阵,一个变换矩阵需要3个基向量。广告牌技术是young的基向量通常就是表面发线(normal)、指向上的方向(up)以及指向右的方向。除此之外,我们还需要指定一个锚点,这个锚点在旋转过程中是固定不变的,以此来确定多边形在空间中的位置。
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
Shader "Unlit/Billboard"
{
Properties
{
//广告牌显示的透明纹理
_MainTex ("Texture", 2D) = "white" {}
//整体颜色
_Color ("Color", Color) = (1,1,1,1)
//调整时固定法线还是固定指向上的方向,即约束垂直方向的程度。
_VerticalBillboarding ("Vertical Restraints", Range(0,1)) = 1
}
SubShader
{
Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent" "DisableBatching"="True" }
LOD 100
Pass
{
Tags { "LightMode"="ForwardBase" }
ZWrite Off
Blend SrcAlpha OneMinusSrcAlpha
Cull Off
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
// make fog work
#pragma multi_compile_fog
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 texcoord : TEXCOORD0;
};
struct v2f
{
float2 uv : TEXCOORD0;
float4 pos : SV_POSITION;
};
sampler2D _MainTex;
float4 _MainTex_ST;
float4 _Color;
float _VerticalBillboarding;
v2f vert (appdata v)
{
v2f o;
//首先选择模型空间的原点作为广告牌的锚点,并利用内置变量获取模型空间下的视角位置:
float3 center = float3(0, 0, 0);
float3 viewer = mul(_World2Object, float4(_WorldSpaceCameraPos, 1));
//然后,开始计算3个正交矢量。首先,我们根据观察位置和锚点计算目标法线方向,并根据_VerticalBillboarding属性来控制垂直方向上的约束。当_VerticalBillboarding为1时,意味着法线方向固定为视角方向;当_VerticalBillboarding为0时,意味着向上方向固定为(0,1,0)。最后,我们需要计算得到的法线方向进行归一化操作来得到单位矢量。
float3 normalDir = viewer - center;
normalDir.y = normalDir.y * _VerticalBillboarding;
normalDir = normalize(normalDir);
//接着,我们得到了粗略的向上方向。为了防止法线方向和向上方向平行(如果平行,那么叉积得到的结果将是错误的),我们对法线方向的y分量进行判断,以得到合适的向上方向。然后,根据法线方向和粗略的向上方向得到向右方向,并对结果进行归一化。
float3 upDir = abs(normalDir.y) > 0.999 ? float3(0, 0, 1) : float3(0, 1, 0);
float3 rightDir = normalize(cross(upDir, normalDir));
upDir = normalize(cross(normalDir, rightDir));
//这样,我们得到了所需的3个正交基矢量。我们根据原始的位置相对于锚点的偏移量以及3个正交基矢量,以计算得到新的顶点位置:
float3 centerOffs = v.vertex.xyz - center;
float3 localPos = center + rightDir * centerOffs.x + upDir * centerOffs.y + normalDir.z * centerOffs.z;
//最后,把模型空间的顶点位置变换到裁剪空间中:
o.pos = mul(UNITY_MATRIX_MVP, float4(localPos, 1));
return o;
}
fixed4 frag (v2f i) : SV_Target
{
fixed4 c = tex2D(_MainTex, i.uv);
c.rgb *= _Color.rgb;
return c;
}
ENDCG
}
}
}
如果我们在模型空间下进行了一些顶点动画,那么批处理往往就会破坏这种动画效果。这时,我们可以通过SubShader的DisableBatching标签来强制取消对该Shader的批处理。但是,取消批处理会带来一定的性能下降,增加DrawCall。因此我们应该尽量避免使用模型空间下的一些绝对位置和方向来进行计算。
其次,如果我们想要对包含了顶点动画的物体添加阴影,我们就需要提供一个自定义的ShadowCaster Pass,在这个Pass中,我们将进行同样的顶点变换过程。