Shader学习的基础知识（五）渐变纹理

这个例子比较简单没什么新内容，直接上代码亲门一看就能懂的，不懂的看我以前的例子。效果如图:

Shader "Custom/TestShader12" {
	Properties{
		_Color("Color Tint",Color)=(1,1,1,1)
		_RampTex("Ramp Tex",2D)="white"{}
		_Specular("Specular",Color)=(1,1,1,1)
		_Gloss("Gloss",Range(8,256))=20
	}
	SubShader{
	Pass{
		Tags{"LightMode"="ForwardBase"}
		CGPROGRAM
		#pragma vertex vert
		#pragma fragment frag
		#include "Lighting.cginc"

		fixed4 _Color;
		sampler2D _RampTex;
		float4 _RampTex_ST;
		fixed4 _Specular;
		float _Gloss;

		//Appction To Vertex
		struct a2v{
			float4 vertex:POSITION;
			float3 normal:NORMAL;
			float4 texcoord:TEXCOORD0;
		};
		//Vertex To Fragment
		struct v2f{
			float4 pos:SV_POSITION;
			float3 worldNormal:TEXCOORD0;
			float3 worldPos:TEXCOORD1;
			float2 uv:TEXCOORD2;
		};

		v2f vert(a2v v){
			v2f o;
			o.pos=UnityObjectToClipPos(v.vertex);
			o.worldNormal=UnityObjectToWorldNormal(v.normal);
			o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
			o.uv=TRANSFORM_TEX(v.texcoord,_RampTex);

			return o;
		}

		float4 frag(v2f i):SV_TARGET{
			//取世界空间法线
			fixed3 worldNormal=normalize(i.worldNormal);
			//取世界空间灯光方向
			fixed3 worldLightDir=normalize(UnityWorldSpaceLightDir(i.worldPos));

			//环境光
			fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

			//漫反身 半兰伯特光照 这里的亮度的取值范围是0~1
			fixed halfLambert =0.5*dot(worldNormal,worldLightDir)+0.5;
			
			//光照的亮度用来作UV使用 也就通过亮度在原图中取样，比如：
			//0.5这个变度的，就取UV(0.5,0.5)位置的纹素作为颜色
			fixed3 diffuseColor = tex2D(_RampTex,fixed2(halfLambert,halfLambert)).rgb*_Color.rgb;

			//灯光色
			fixed3 diffuse = _LightColor0.rgb*diffuseColor;
			fixed3 viewDir=normalize(UnityWorldSpaceViewDir(i.worldPos));
			fixed3 halfDir=normalize(worldLightDir+viewDir);
			//高光光照
			fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(worldNormal,halfDir)),_Gloss);

			return fixed4(ambient+diffuse+specular,1.0);
		}
		ENDCG
	}
	}
}