编译错误MS Access SQL

Question

我得到一个编译错误：“参数不是可选的” 基本上在这段代码中，我试图围绕表格样式自动分配。当代码被调用时，它开始于AssignNullProjects()，当我得到的错误，GetNextAssignee是亮点中的一部分" & GetNextAssignee & "

我真的不知道如何解决它，这是我下面全码：

Public Function AssignNullProjects() As Long 

    Dim db As dao.Database 
    Dim rs As dao.Recordset 
    Dim strSQL As String 

    Set db = CurrentDb 
    strSQL = "SELECT CFRRRID, [program], [language] FROM CFRRR WHERE assignedto Is Null" 
    Set rs = db.OpenRecordset(strSQL, dbOpenDynaset) 
    If Not rs.BOF And Not rs.EOF Then 
     While Not rs.EOF 
      strSQL = "UPDATE CFRRR SET assignedto = " & GetNextAssignee & ", assignedby = " & [Forms]![CFRRR]![assignedby] & ", Dateassigned = #" & Now & "#, actiondate = #" & Now & "#, Workername = " & _ 
           [Forms]![CFRRR]![assignedto] & ", WorkerID = " & [Forms]![CFRRR]![assignedto] & " WHERE CFRRRID = " & rs!CFRRRID 

      db.Execute strSQL, dbFailOnError 
      rs.MoveNext 
     Wend 
    End If 

    rs.Close 
    db.Close 
    Set rs = Nothing 
    Set db = Nothing 

End Function 

Public Function GetNextAssignee(program As String, Language As String) As Long 
' Returns UserID as a Long Integer with the lowest [TS] value, 
' and updates same [TS] by incremented with 1. 

    Dim db As dao.Database 
    Dim rs As dao.Recordset 
    Dim strSQL As String 

    Set db = CurrentDb 
    strSQL = "SELECT TOP 1 WorkerID FROM attendance WHERE [Programs] LIKE '*" & program & "*' AND [Language] = '" & Language & "' AND [Status] = '" & Available & "' ORDER BY TS ASC" 
    Set rs = db.OpenRecordset(strSQL, dbOpenDynaset) 
    If Not rs.BOF And Not rs.EOF Then 
     'Found next assignee, update date/time stamp 
'  strSQL = "UPDATE tblUser SET TS = " & DMax("[TS]", tblUser) + 1 & " WHERE [WorkerID]= " & rs!workerid 
     strSQL = "UPDATE attendance SET TS = " & DMax("[TS]", "attendance") + 1 & " WHERE [WorkerID]= " & rs!workerid 
     db.Execute strSQL, dbFailOnError 
     GetNextAssignee = rs!workerid 
    Else 
     'Field TS has NO VALUE FOR ALL RECORDS! 
     'Code calling this function should check for a return of 0 indicating an error. 
     GetNextAssignee = 0 
    End If 

    rs.Close 
    db.Close 
    Set rs = Nothing 
    Set db = Nothing 

End Function 

Answer 1

当你调用这个函数，你必须提供2个参数（字符串值）：

Public Function GetNextAssignee(program As String, Language As String) As Long 

但构建UPDATE语句时，你叫塔没有提供所需的参数t的函数：

strSQL = "UPDATE CFRRR SET assignedto = " & GetNextAssignee & ", assignedby = " 

这样进出抱怨那些（串）参数是不可选的 - 你必须提供他们。当你给函数像这样2串代码应该编译...

strSQL = "UPDATE CFRRR SET assignedto = " & GetNextAssignee("foo", "bar") & ", assignedby = " 

尽管代码将与这些字符串编译，功能可能不会返回你所需要的结果。因此用实际值代替foo和bar。