如何在Delphi中使用ADO读取TBlobField中的数据？

Question

我正在尝试使用TADOBlobStream从TBlobField读取数据。我写了下面的功能

function DecompressBlobFieldCustom(AField:TBlobField):String; 
    var 
     BLOBStream:TADOBlobStream; 
     Size:Integer; 
    begin 
     BLOBStream:= TADOBlobStream.Create(AField,bmRead); 
     Size:= BLOBStream.Size; 
     BLOBStream.Read(Result,Size); 
    end; 

我用的功能如下

Data := DecompressBlobFieldCustom(FldImage); 

但是，当我尝试做if Length(Data) > 0 then我收到Access violation at address XXXX错误。我无法弄清楚问题所在。请帮忙。

Answer 1

Result是一个字符串类型，但是一个blob流操作字节数组。尝试将字节数组当作字符串处理通常是个错误。此外，你没有分配一个缓冲区来读取，这是错误的真正原因。

读入一个字节数组这样的：

function ReadBlobField(Field: TBlobField): TBytes; 
var 
    Stream: TStream; 
begin 
    Stream := TADOBlobStream.Create(Field, bmRead); 
    try 
    SetLength(Result, Stream.Size); 
    if Stream.Size>0 then 
     Stream.ReadBuffer(Result[0], Stream.Size); 
    finally 
    Stream.Free; 
    end; 
end; 

它是优选使用的TDataSet的CreateBlobStream方法创建BLOB流，如在讨论documentation。所以代码会是这样的更好：

function ReadBlobField(DataSet: TDataSet; Field: TField): TBytes; 
var 
    Stream: TStream; 
begin 
    Stream := DataSet.CreateBlobStream(Field, bmRead); 
    try 
    SetLength(Result, Stream.Size); 
    if Stream.Size>0 then 
     Stream.ReadBuffer(Result[0], Stream.Size); 
    finally 
    Stream.Free; 
    end; 
end; 

我假设数据真的是一个字节数组，并没有保存文本。事实上，它是在一个blob举行表明，如提及减压和图像。

一些其他意见：

1. 当你完成它，你必须销毁流。
2. 通常优选使用ReadBuffer而不是Read，因为如果未读取请求的字节数，ReadBuffer会引发异常。