复制一个文件，在那里有100个文件和100个文件夹使用批处理文件

Question

我有两个文件夹CopyFrom和CopyTo其中CopyFrom具有命名为1.txt ... 100.txt 100个的文本文件，并在CopyTo文件夹我有100个拷贝一次一个文件夹文件夹为F1 ... F100。现在，我想将CopyFrom文件夹中的一个文件复制到CopyTo中的一个文件夹中，以便F1将包含1.txt,F2将包含2.txt，...，F100将包含100.txt文件。

我知道复制我可以使用类似For /d %%a in (C:\Users\me\Desktop\ShortCuts\*) do xcopy "C:\Users\me\Desktop\Time.xls" "%%a"所有文件夹，但我无法找到一种方法，不同的文件复制到不同的文件夹。

我可以重复所有文件(For %%a in (C:\Users\me\Desktop\ShortCuts\*) Echo "%%a")在CopyFrom文件夹中，也可以回声CopyTo文件夹中的所有文件夹，但不能想出用两种工作得到我所期待的。

Answer 1

假设源位置包含的文件1.txt只100.txt和目标位置已经包含了所有F1到F100目录，下面的代码片段可能会为你工作：

@echo off 
setlocal EnableExtensions DisableDelayedExpansion 

rem // Define constants here: 
set "Pattern=*.txt" 
set "CopyFrom=." 
set "CopyTo=D:\Target" 

for %%F in ("%CopyFrom%\%Pattern%") do (
    ECHO copy "%%~F" "%CopyTo%\F%%~nF\" 
) 

endlocal 
exit /B 

有没有枚举完成的目标位置，复制目标只是从源文件名派生而来。

在测试脚本后，删除大写ECHO命令以实际复制文件！

Answer 2

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    rem Configure paths 
    set "copyFrom=c:\somewhere" 
    set "copyTo=c:\anotherPlace" 

    rem Generate two lists, one with files and one with folders 
    dir /b /a-d "%copyFrom%\*" > "%temp%\copyFromFiles.txt" 
    dir /b /ad "%copyTo%\*" > "%temp%\copyToFolders.txt" 

    rem Assign each list as input to two streams and start processing  
    9< "%temp%\copyFromFiles.txt" 8< "%temp%\copyToFolders.txt" (
     call :matchFromWithTo 
    ) 

    rem Remove generated lists 
    del "%temp%\copyFromFiles.txt" 
    del "%temp%\copyToFolders.txt" 

    rem End 
    goto :eof 

:matchFromWithTo 
    rem Read file from stream 9 and leave if nothing read 
    <&9 set /p "file=" || goto :eof 
    rem Read folder from stream 8 and leave if nothing read 
    <&8 set /p "folder=" || goto :eof 

    rem Do the copy (debug: we will only echo the command) 
    echo copy "%copyFrom%\%file%" "%copyTo%\%folder%" 

    rem Keep reading until all files or folders are processed 
    goto :matchFromWithTo