您的位置: 首页  >  技术问答  >  winforms网页浏览器控件中的JavaScript访问问题

winforms网页浏览器控件中的JavaScript访问问题

分类: 技术问答 • 2025-09-17 14:16:34
问题描述：

ETA：我已经有了它，答案在下面发布。我会标记任何人可以解释到底发生了什么以及如何清理它的答案。winforms网页浏览器控件中的JavaScript访问问题

我有一个类，其中包含一个窗体与WinForms的浏览器控件来显示一个HTML页面。我在页面的头部插入了一些脚本，以便查询有关样式的信息。

当我从可执行文件启动应用程序时，一切正常。不过，我现在试图在设计时从外接程序启动应用程序。会发生什么情况是右键单击.htm类型文件并单击以启动浏览器。然后加载项启动导航到提供的.htm文件路径的浏览器。

我注意到的第一件事是，浏览器现在显示此消息：

“为帮助保护您的安全，您的浏览器已经限制显示可能访问您的计算机的活动内容文件点击这里。选项...“

然后我注意到，即使点击启用活动内容，我的所有javascript调用都失败了。

作为一个测试，我想这简单的JavaScript调用（没有明确注入）：

Me.Document.InvokeScript("execScript", New Object() {"alert('hello');", "JavaScript"})

这将导致一个JavaScript错误对话框，说：“访问被拒绝”

所以，这是一个安全问题。不是我想要但是，我试图暂时降低IE中的所有安全级别，但这没有什么区别。

我应该补充说，该应用程序包含2个浏览器控件。第二个托管通过设置浏览器的属性创建的网页。这不会遭受javascript访问问题。

ETA：我一直在寻找IInternetSecurityManager，这可能与此有关吗？我希望不会:(

答

我设法得到它与IInternetSecurityManager的工作是由WebBrowser控件的网站返回的服务。 我得到了它在URL中ProcessUrlAction方法返回好吧，无论工作。

我从我在互联网上找到位这个那儿剽窃在一起，如果有人能指出它是如何进行清理，限制在企业内部网的话，我会庆祝，作为答案。

我相信我需要在ProcessUrlAction中检查url，并根据其内容返回Ok或Default。

下面的代码：

Friend Class MainBrowser 
Inherits WebBrowser 

Private _Site As WebBrowserSite 
Protected Overrides Function CreateWebBrowserSiteBase() As WebBrowserSiteBase 
    If _Site Is Nothing Then 
     _Site = New WebBrowserSite(Me) 
    End If 
    Return _Site 
End Function 

Protected Class WebBrowserSite 
    Inherits System.Windows.Forms.WebBrowser.WebBrowserSite 
    Implements NativeInterfaces.IServiceProvider 
    Implements NativeInterfaces.IInternetSecurityManager 

    Private Const INET_E_DEFAULT_ACTION As Integer = &H800C0011 
    Private Const S_OK As Integer = 0 
    Private Const E_NOINTERFACEX As Integer = &H80004002 

    Private Shared IID_IInternetSecurityManager As Guid = Marshal.GenerateGuidForType(GetType(NativeInterfaces.IInternetSecurityManager)) 

    Private Owner As MainBrowser 

    Public Sub New(ByVal owner As MainBrowser) 
     MyBase.New(owner) 
     owner = owner 
    End Sub 

    Public Function QueryService(ByRef guidService As System.Guid, ByRef riid As System.Guid, ByRef ppvObject As System.IntPtr) As Integer Implements NativeInterfaces.IServiceProvider.QueryService 
     If guidService = IID_IInternetSecurityManager AndAlso riid = IID_IInternetSecurityManager Then 
      ppvObject = Marshal.GetComInterfaceForObject(Me, GetType(NativeInterfaces.IInternetSecurityManager)) 
      Return S_OK 
     End If 
     ppvObject = IntPtr.Zero 
     Return E_NOINTERFACEX 
    End Function 

    Public Function GetSecurityId(ByVal pwszUrl As String, ByVal pbSecurityId As System.IntPtr, ByRef pcbSecurityId As UInteger, ByRef dwReserved As UInteger) As Integer Implements NativeInterfaces.IInternetSecurityManager.GetSecurityId 
     Return INET_E_DEFAULT_ACTION 
    End Function 

    Public Function GetSecuritySite(ByRef pSite As System.IntPtr) As Integer Implements NativeInterfaces.IInternetSecurityManager.GetSecuritySite 
     pSite = IntPtr.Zero 
     Return INET_E_DEFAULT_ACTION 
    End Function 

    Public Function SetSecuritySite(ByVal pSite As System.IntPtr) As Integer Implements NativeInterfaces.IInternetSecurityManager.SetSecuritySite 
     Return INET_E_DEFAULT_ACTION 
    End Function 

    Public Function MapUrlToZone(ByVal pwszUrl As String, ByRef pdwZone As UInteger, ByVal dwFlags As UInteger) As Integer Implements NativeInterfaces.IInternetSecurityManager.MapUrlToZone 
     pdwZone = 0 // URLZONE_LOCAL_MACHINE ? 
     Return S_OK // no difference 
     // Return INET_E_DEFAULT_ACTION 
    End Function 

    Public Function ProcessUrlAction(ByVal pwszUrl As String, ByVal dwAction As UInteger, ByVal pPolicy As System.IntPtr, ByVal cbPolicy As UInteger, ByVal pContext As System.IntPtr, ByVal cbContext As UInteger, ByVal dwFlags As UInteger, ByVal dwReserved As UInteger) As Integer Implements NativeInterfaces.IInternetSecurityManager.ProcessUrlAction 
     // Return INET_E_DEFAULT_ACTION 
     Return S_OK // This is what made the difference 
    End Function 

    Public Function QueryCustomPolicy(ByVal pwszUrl As String, ByRef guidKey As System.Guid, ByRef ppPolicy As System.IntPtr, ByRef pcbPolicy As UInteger, ByVal pContext As System.IntPtr, ByVal cbContext As UInteger, ByVal dwReserved As UInteger) As Integer Implements NativeInterfaces.IInternetSecurityManager.QueryCustomPolicy 
     ppPolicy = IntPtr.Zero 
     pcbPolicy = 0 
     Return INET_E_DEFAULT_ACTION 
    End Function 

    Public Function SetZoneMapping1(ByVal dwZone As UInteger, ByVal lpszPattern As String, ByVal dwFlags As UInteger) As Integer Implements NativeInterfaces.IInternetSecurityManager.SetZoneMapping 
     Return INET_E_DEFAULT_ACTION 
    End Function 

    Public Function GetZoneMappings(ByVal dwZone As UInteger, ByRef ppenumString As System.Runtime.InteropServices.ComTypes.IEnumString, ByVal dwFlags As UInteger) As Integer Implements NativeInterfaces.IInternetSecurityManager.GetZoneMappings 
     ppenumString = Nothing 
     Return INET_E_DEFAULT_ACTION 
    End Function 

End Class 

End Class

的接口：

<ComImport(), InterfaceType(ComInterfaceType.InterfaceIsIUnknown), Guid("6d5140c1-7436-11ce-8034-00aa006009fa")> _ 
Interface IServiceProvider 
    <PreserveSig()> _ 
    Function QueryService(ByRef guidService As Guid, ByRef riid As Guid, ByRef ppvObject As IntPtr) As <MarshalAs(UnmanagedType.I4)> Integer 
End Interface 


<ComImport(), GuidAttribute("79EAC9EE-BAF9-11CE-8C82-00AA004BA90B"), InterfaceTypeAttribute(ComInterfaceType.InterfaceIsIUnknown)> _ 
Public Interface IInternetSecurityManager 
    <PreserveSig()> _ 
    Function SetSecuritySite(<[In]()> ByVal pSite As IntPtr) As <MarshalAs(UnmanagedType.I4)> Integer 

    <PreserveSig()> _ 
    Function GetSecuritySite(ByRef pSite As IntPtr) As <MarshalAs(UnmanagedType.I4)> Integer 

    <PreserveSig()> _ 
    Function MapUrlToZone(<[In](), MarshalAs(UnmanagedType.LPWStr)> ByVal pwszUrl As String, ByRef pdwZone As UInt32, <[In]()> ByVal dwFlags As UInt32) As <MarshalAs(UnmanagedType.I4)> Integer 

    <PreserveSig()> _ 
    Function GetSecurityId(<[In](), MarshalAs(UnmanagedType.LPWStr)> ByVal pwszUrl As String, <Out()> ByVal pbSecurityId As IntPtr, <[In](), Out()> ByRef pcbSecurityId As UInt32, <[In]()> ByRef dwReserved As UInt32) As <MarshalAs(UnmanagedType.I4)> Integer 

    <PreserveSig()> _ 
    Function ProcessUrlAction(<[In](), MarshalAs(UnmanagedType.LPWStr)> ByVal pwszUrl As String, ByVal dwAction As UInt32, ByVal pPolicy As IntPtr, ByVal cbPolicy As UInt32, ByVal pContext As IntPtr, ByVal cbContext As UInt32, _ 
     ByVal dwFlags As UInt32, ByVal dwReserved As UInt32) As <MarshalAs(UnmanagedType.I4)> Integer 

    <PreserveSig()> _ 
    Function QueryCustomPolicy(<[In](), MarshalAs(UnmanagedType.LPWStr)> ByVal pwszUrl As String, ByRef guidKey As Guid, ByRef ppPolicy As IntPtr, ByRef pcbPolicy As UInt32, ByVal pContext As IntPtr, ByVal cbContext As UInt32, _ 
     ByVal dwReserved As UInt32) As <MarshalAs(UnmanagedType.I4)> Integer 

    <PreserveSig()> _ 
    Function SetZoneMapping(ByVal dwZone As UInt32, <[In](), MarshalAs(UnmanagedType.LPWStr)> ByVal lpszPattern As String, ByVal dwFlags As UInt32) As <MarshalAs(UnmanagedType.I4)> Integer 

    <PreserveSig()> _ 
    Function GetZoneMappings(<[In]()> ByVal dwZone As UInt32, ByRef ppenumString As ComTypes.IEnumString, <[In]()> ByVal dwFlags As UInt32) As <MarshalAs(UnmanagedType.I4)> Integer 
End Interface

相关推荐