使用批量分割IP和端口的IP：端口格式使用批量

问题描述：

对于我目前正在使用的程序我采取了一个值，它是ip：port格式的代理，我需要能够将IP和端口分割为不同的变量，以便不同的程序，需要ip和端口分开将能够工作。该程序基本上是一个用于minecraft的自动ip /代理切换器，仅出于游戏原因，除了实际更改代理的部分外，我拥有所有代码。我没有收到任何错误消息，只是我实际上不知道要写什么代码。无论如何，这是我的代码。使用批量分割IP和端口的IP：端口格式使用批量

@echo off 
color b 
title minecraft proxy switcher 
set nLine=0 
echo input full path to text file containing proxies 
set /P "filepath=>" 
echo end >> %filepath% 
:top 
cls 
set /A nLine=%nLine%+1 
echo now at proxy number %nLine% 
CALL :ReadNthLine "%filepath%" %nLine% 
PAUSE >NUL & goto:top 
GOTO :EOF 
::*************************************************************************************** 
:ReadNthLine File nLine 
FOR /F %%A IN ('^<"%~1" FIND /C /V ""') DO IF %2 GTR %%A (ECHO Error: No such line %2. 1>&2 & EXIT /b 1) 
FOR /F "tokens=1* delims=]" %%A IN ('^<"%~1" FIND /N /V "" ^| FINDSTR /B /C:"[%2]"') DO set http_proxy=%%B 
goto finish 
::*************************************************************************************** 
:finish 
if %http_proxy%==end (
       cls 
       echo all proxies have been used 
       echo will return to top of list in 5 seconds 
       TIMEOUT /T 5 /NOBREAK 
       set nLine=0 
       goto top 
      ) 
java -DsocksProxyHost=ip -DsocksProxyPort=port -Xmx800m -jar MinecraftLauncher.exe 
echo New ip is %http_proxy% 
echo waiting for user input 
echo press any key for a new ip 
pause 
goto top

任何帮助是极大的赞赏，如果你还注意到了一些事，那就是写的不好或不正确的在我的代码，请告诉我。

有助于查看输入文件的样子，因此我们知道要解析出哪些文件。 – Squashman

输入文件是使用ip：port格式的代理服务器列表，例如：127.0.0.1:80 192.168.1.1:8080等等 –

答

与for分割字符串，用正确的令牌和分隔符：

set "line=192.168.1.1:8080" 
for /f "tokens=1,2 delims=:" %%a in ("%line%") do (
    set server=%%a 
    set port=%%b 
) 
echo Server %server% Port %port%

这里是一个基本的代码框架，其处理线后的文件行（你的工作方式，但是这是比较容易的方式）：

@echo off 
set /p "filepath=File: " 

:top 
set n=0 
for /f "tokens=1,2 delims=:" %%a in (%filepath%) do call :process %%a %%b 
timeout 5 
goto :top 

:process 
echo trying %n% 
set /a n+=1 
echo host: %1 
echo port: %2 
pause 
goto :eof

使用批量分割IP和端口的IP：端口格式使用批量

相关推荐