存储管理器
一存储寄存器的性质：
存储管理器负责管理2440的所有内存设备，2440的地址线ADDR0~ADDR26，即最大执行寻址2^27=128M空间。 CPU通过8根片选信号nGCS0~nGCS7，控制bank0~bank7，每个bank大小为128M，这样就实现了须知1G地址空间。
2440是32位的CPU，地址空间应该为4GB，除以上1GB空间用来连接外设外，还有一部分是CPU内部寄存器的地址，剩下的地址空间没有使用，寄存器空间的地址是0X48000000~0X5FFFFFFF 。
不同的bank可以接不同的外设设备，2440对多允许接入8个外设。CPU寻址时，向内存管理器发送地址，内存管理器负责访问不同的外设。 下图为开发板上所接的外设：
对于具体的片选信号、bank选择信号、列地址、行地址等等与硬件相关的不需要cpu去管，这些工作由存储管理器完成。
存储管理器能够根据硬件具体的配置信息来决定如何对硬件进行访问。想要访问一个芯片时，有哪些配置信息？
1.地址线
2.数据宽度（8/16/32位）
3.时钟/频率
4.芯片相关的特性：（对于SDRAM的寻址由行地址（多少位？）、列地址、BANK决定（多少位？多少个BANK？））
本开发板上使用的SDRAM，列地址有9位，行地址为13位，4个BANK。需要注意的是，芯片的地址线与2440链接时，地址线不是一一对应连接的，A0对应的2440的A2。
第1种相当于将地址左移了2位，乘以了4，第2相当于将地址值左移了一位，乘以了2倍。
二存储寄存器的使用-访问SDRAM
对于SRAM，可以直接读写，但SDRAM不同的是地址分为列、行、BANK，且需要不断地刷新。
1.对于启动文件head.s：
.equ MEM_CTL_BASE, 0x48000000
.equ SDRAM_BASE, 0x30000000
.text
.global _start
_start:
bl disable_watch_dog @ 关闭WATCHDOG，否则CPU会不断重启
bl memsetup @ 设置存储控制器
bl copy_steppingstone_to_sdram @ 复制代码到SDRAM中
ldr pc, =on_sdram @ 从片内内存跳到SDRAM中继续执行，上电后默认的是从0地址开始运行，在此句之前，由于位置无关码，程序在片内内存中顺序执行（为什么此句能够跳转过去，是由于MAKEFILE改了链接地址，地址值是从0x30000000开始计数，on_sdram=0x30000000+10，则pc=0x30000010，在SDRAM中）
on_sdram:
ldr sp, =0x34000000 @ 设置堆栈
bl main
halt_loop:
b halt_loop
disable_watch_dog:
@ 往WATCHDOG寄存器写0即可
mov r1, #0x53000000
mov r2, #0x0
str r2, [r1]
mov pc, lr @ 返回
copy_steppingstone_to_sdram:
@ 将Steppingstone（片内内存）的4K数据全部复制到SDRAM中去
@ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000
mov r1, #0 // 片内内存地址从0开始的
ldr r2, =SDRAM_BASE
mov r3, #4*1024
1:
ldr r4, [r1],#4 @ 从Steppingstone读取4字节的数据，并让源地址加4
str r4, [r2],#4 @ 将此4字节的数据复制到SDRAM中，并让目地地址加4
cmp r1, r3 @ 判断是否完成：源地址等于Steppingstone的未地址？
bne 1b @ 若没有复制完，继续
mov pc, lr @ 返回
memsetup:
@ 设置存储控制器以便使用SDRAM等外设
mov r1, #MEM_CTL_BASE @ 存储控制器的13个寄存器的开始地址
adrl r2, mem_cfg_val @ 这13个值的起始存储地址
add r3, r1, #52 @ 13*4 = 54
1:
ldr r4, [r2], #4 @ 读取设置值，并让r2加4
str r4, [r1], #4 @ 将此值写入寄存器，并让r1加4
cmp r1, r3 @ 判断是否设置完所有13个寄存器
bne 1b @ 若没有写成，继续
mov pc, lr @ 返回
.align 4
mem_cfg_val:
@ 存储控制器13个寄存器的设置值
.long 0x22011110 @ BWSCON
.long 0x00000700 @ BANKCON0
.long 0x00000700 @ BANKCON1
.long 0x00000700 @ BANKCON2
.long 0x00000700 @ BANKCON3
.long 0x00000700 @ BANKCON4
.long 0x00000700 @ BANKCON5
.long 0x00018005 @ BANKCON6
.long 0x00018005 @ BANKCON7
.long 0x008C07A3 @ REFRESH
.long 0x000000B1 @ BANKSIZE
.long 0x00000030 @ MRSRB6
.long 0x00000030 @ MRSRB7
2.main函数，和上一章LED的一样没变
3.MAKEFILE
sdram.bin : head.S leds.c
arm-linux-gcc -c -o head.o head.S
arm-linux-gcc -c -o leds.o leds.c
arm-linux-ld -Ttext 0x30000000 head.o leds.o -o sdram_elf //链接地址改为SDRAM的地址，表示程序正常运行时从地址0X30000000（sdram）处开始运行
arm-linux-objcopy -O binary -S sdram_elf sdram.bin
arm-linux-objdump -D -m arm sdram_elf > sdram.dis
clean:
rm -f sdram.dis sdram.bin sdram_elf *.o
以上函数实现的功能是将上一章的LED程序烧写到NAND FLASH以后，在启动文件里通过设置相应的寄存器来初始化存储控制器，并将自动从nand flash拷入片内内存的代码从片内内存拷入到SDRAM中，然后从sdram中开始运行程序 。